# Home Manager: everything in your home directory.
{
  config,
  lib,
  ...
}:
{
  imports = [
    ./files.nix
    ./services.nix
    ./shell.nix
    ./theming.nix
    ./packages.nix
  ];

  options.dot = {
    repoPath = lib.mkOption {
      type = lib.types.str;
      default = "${config.home.homeDirectory}/git/dot";
      description = "Where this repo is checked out.";
    };

    liveConfig = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = ''
        Link the hand-edited configs (hypr, waybar, kitty, ...) straight to the
        checkout at repoPath, as the old symlink.sh did: an edit takes effect
        the next time the program reads it, with no rebuild. Off, they are
        copied into the Nix store and change only on a rebuild (the test VM
        does this, since it has no checkout).
      '';
    };
  };

  config = {
    home = {
      username = "vizie";
      homeDirectory = "/home/vizie";
      stateVersion = "26.05";
    };

    xdg.enable = true;
    xdg.userDirs = {
      enable = true;
      createDirectories = true;
      extraConfig.XDG_PROJECTS_DIR = "${config.home.homeDirectory}/Projects";
    };

    programs.home-manager.enable = true;
  };
}