# The NVMe drive, as disko partitions and formats it at install time (see
# MIGRATION.md). Running disko on it erases everything on the drive. The two
# SATA drives (sda, sdb) aren't listed, so disko never touches them.
#
# Same shape as CachyOS had it: an EFI partition for systemd-boot and one btrfs
# partition with subvolumes, compressed with zstd. Swap is zram (base.nix).
let
  mountOptions = [
    "noatime"
    "compress=zstd"
  ];
in
{
  disko.devices.disk.main = {
    type = "disk";
    device = "/dev/disk/by-id/nvme-Samsung_SSD_980_PRO_1TB_S5GXNF1R877751D";
    content = {
      type = "gpt";
      partitions = {
        ESP = {
          size = "2G";
          type = "EF00";
          content = {
            type = "filesystem";
            format = "vfat";
            mountpoint = "/boot";
            mountOptions = [ "umask=0077" ];
          };
        };
        root = {
          size = "100%";
          content = {
            type = "btrfs";
            extraArgs = [ "-f" ];
            subvolumes = {
              "@" = {
                mountpoint = "/";
                inherit mountOptions;
              };
              "@home" = {
                mountpoint = "/home";
                inherit mountOptions;
              };
              "@nix" = {
                mountpoint = "/nix";
                inherit mountOptions;
              };
              "@log" = {
                mountpoint = "/var/log";
                inherit mountOptions;
              };
            };
          };
        };
      };
    };
  };
}