{
  description = "vizie's NixOS desktop: Hyprland, CachyOS kernel and gaming tweaks";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Partitions and formats the drive at install time (hosts/desktop/disko.nix).
    disko = {
      url = "github:nix-community/disko/latest";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # CachyOS kernels, built by the maintainer's CI. Its nixpkgs input is left
    # alone on purpose: overriding it changes the kernel's hash, so nothing comes
    # from the binary cache and the kernel compiles locally.
    nix-cachyos-kernel.url = "github:xddxdd/nix-cachyos-kernel/release";

    imsh-clients = {
      url = "github:echozio/imsh-clients";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Private repo: fetched with git so the gh credential helper can sign in.
    philly = {
      url = "git+https://github.com/Eiziv/philly?ref=master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    { self, nixpkgs, ... }@inputs:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        config.allowUnfree = true;
        overlays = [ self.overlays.default ];
      };
    in
    {
      overlays.default = import ./pkgs;

      # The packages this repo adds or patches, so each can be built on its own:
      #   nix build .#waybar
      packages.${system} = {
        inherit (pkgs)
          waybar
          xembedsniproxy
          signal-desktop-themed
          claude-desktop
          opendeck
          breezex-cursor
          proton-cachyos
          python3-desktop
          ;
      };

      nixosConfigurations.desktop = nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs; };
        modules = [ ./hosts/desktop ];
      };

      formatter.${system} = pkgs.nixfmt;
    };
}